Find Value within Datarange

mfaisal.ce

New member
Joined
Nov 26, 2021
Messages
1
Reaction score
0
Points
0
Excel Version(s)
2010
Hello,

I am trying to find a value between a range but unable to do that, i tried Index & match combination too but unable....

Level 0 10 20 30 40 50 60 70 80 90 100
Volume 0 0.34 0.97 1.75 2.63 3.55 4.47 5.35 6.13 6.76 7.1

I need to find Volume when Level will be 35? I want to use Level and Volume in dynamic range....

Please give me the solution....

regards,
 

Bob Phillips

Super Moderator
Staff member
Joined
Mar 21, 2011
Messages
1,940
Reaction score
0
Points
36
Excel Version(s)
O365
Or maybe you want the trend

=TREND(result_range,lookup_range,lookup_value)
 

p45cal

Super Moderator
Staff member
Joined
Dec 16, 2012
Messages
2,147
Reaction score
1
Points
38
Excel Version(s)
365
To do this one to death…
If you use the TREND formula using all the data, sometimes the results will be significantly off because the relationship is not a straight line:
2021-11-29_124842.png

using the chart, you'd expect a volume of roughly 2.2 for level 35.

Using a straight line through all the points you get 2.55 (dotted line on chart)
Formula:
=TREND(D2:D12,C2:C12,F3,FALSE)

You can get better results using the small straight line between the points directly before and after 35, this gives you 2.19
Formula:
=TREND(INDEX(D2:D12,MATCH(F3,C2:C12)):INDEX(D2:D12,MATCH(F3,C2:C12)+1),INDEX(C2:C12,MATCH(F3,C2:C12)):INDEX(C2:C12,MATCH(F3,C2:C12)+1),F3)
or a bit shorter:
=TREND(OFFSET(C2:C12,MATCH(F3,C2:C12)-1,1,2),OFFSET(C2:C12,MATCH(F3,C2:C12)-1,0,2),F3)

You'll very likely get even better results using the fifth order polynomial (the what?) which is a good fit, which, surprisingly has a simpler (well, shorter) formula, and this gives you 2.18
Formula:
=SUMPRODUCT(LINEST(D2:D12,C2:C12^{1,2,3,4,5},FALSE),F3^{5,4,3,2,1,0})

See attached workbook where you can alter the value in cell F3 (light green).

Dead horse flogged.
 

Attachments

  • ExcelGuru11382.xlsx
    17.2 KB · Views: 3
Last edited:

p45cal

Super Moderator
Staff member
Joined
Dec 16, 2012
Messages
2,147
Reaction score
1
Points
38
Excel Version(s)
365
Top